이 문제는 unique-pairs 프로시저를 만들어

prime-sum-pairs 프로시저의 정의를 줄이는 문제입니다.

하지만 이미 본문에서 unique-pairs 프로시저에 대해 적었기에

그것을 그대로 가져와 옮겨 적기만 하면 되었습니다.

unique-pairs와 prime-sum-pairs 모두 잘 작동하네요.^^

참조

해럴드 애빌슨, 김재우 역, <컴퓨터 프로그램의 구조와 해석>, 인사이트, 2007, pp. 162

; accumulate
(define (accumulate op initial sequence)
  (if (null? sequence)
      initial
      (op (car sequence)
          (accumulate op initial (cdr sequence)))))
; enumerate-interval
(define (enumerate-interval low high)
  (if (> low high)
      null
      (cons low (enumerate-interval (+ low 1) high))))
; flapmap
(define (flatmap proc seq)
  (accumulate append null (map proc seq)))
; prime-sum
(define (prime-sum? pair)
  (prime? (+ (car pair) (cadr pair))))
; make-pair-sum
(define (make-pair-sum pair)
  (list (car pair) (cadr pair) (+ (car pair) (cadr pair))))
; filter
(define (filter predicate sequence)
  (cond ((null? sequence) null)
        ((predicate (car sequence))
         (cons (car sequence)
               (filter predicate (cdr sequence))))
        (else (filter predicate (cdr sequence)))))
; prime
(define (smallest-divisor n)
  (find-divisor n 2))
(define (find-divisor n test-divisor)
  (cond ((> (square test-divisor) n) n)
        ((divides? test-divisor n) test-divisor)
        (else (find-divisor n (+ test-divisor 1)))))
(define (divides? a b)
  (= (remainder b a) 0))
(define (prime? n)
  (= n (smallest-divisor n)))
(define (square x) (* x x))

; answer
(define (unique-pairs n)
  (flatmap (lambda (i)
                  (map (lambda (j) (list i j))
                       (enumerate-interval 1 (- i 1))))
           (enumerate-interval 1 n)))

(define (prime-sum-pairs n)
  (map make-pair-sum
       (filter prime-sum? (unique-pairs n))))

; execute
(unique-pairs 5)
(prime-sum-pairs 5)

크리에이티브 커먼즈 라이선스

이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이선스에 따라 이용하실 수 있습니다.