이 문제는 글자 메시지를 비트로 바꾸는 encode 프로시저를 만드는 문제입니다.

이미 큰 틀은 잡혀 있으니 한 글자만 살펴 비트로 바꾸는 프로시저인

encode-symbol만 만들면 됩니다.

잘 되는군요.^^

이 프로시저를 만드는데 문제점이 들어났습니다.

바로 어떤 프로시저를 만들어야 하는가 잊어먹은 것입니다.

제가 만들어야 할 것은 한 글자만을 찾으면 되는 것입니다.

하지만 중간에 '내가 만드는 것은 encode이니 문자 전체를 생각해야겠군.'이라며

프로시저 안에 프로시저를 하나 더 만들었습니다.

그러니 상당히 복잡해지고 어려워졌습니다.

잠시 마음을 비우고 살펴보니 제가 할 것을 알게되었고,

거기에 맞춰 알고리즘을 간단히 만들고 테스트를 해보니 잘 되더군요.

다음부터 프로시저를 만들 때 인자와 리턴, 해야할 일을 명확히 해야겠습니다.

그래서 다층 설계(stratified design)를 하라고 하는군요.^^

참조

해럴드 애빌슨, 김재우 역, <컴퓨터 프로그램의 구조와 해석>, 인사이트, 2007, pp. 218

(define true (= 0 0))
(define false (= 0 1))
; section 2.3.3
(define (element-of-set? x set)
  (cond ((null? set) false)
        ((equal? x (car set)) true)
        (else (element-of-set? x (cdr set)))))

; section 2.3.4
(define (make-leaf symbol weight)
  (list 'leaf symbol weight))
(define (leaf? object)
  (eq? (car object) 'leaf))
(define (symbol-leaf x) (cadr x))
(define (weight-leaf x) (caddr x))
(define (make-code-tree left right)
  (list left
        right
        (append (symbols left) (symbols right))
        (+ (weight left) (weight right))))
(define (left-branch tree) (car tree))
(define (right-branch tree) (cadr tree))
(define (symbols tree)
  (if (leaf? tree)
      (list (symbol-leaf tree))
      (caddr tree)))
(define (weight tree)
  (if (leaf? tree)
      (weight-leaf tree)
      (cadddr tree)))

; decoding
(define (decode bits tree)
  (define (decode-1 bits current-branch)
    (if (null? bits)
        '()
        (let ((next-branch
               (choose-branch (car bits) current-branch)))
          (if (leaf? next-branch)
              (cons (symbol-leaf next-branch)
                    (decode-1 (cdr bits) tree))
              (decode-1 (cdr bits) next-branch)))))
  (decode-1 bits tree))
(define (choose-branch bit branch)
  (cond ((= bit 0) (left-branch branch))
        ((= bit 1) (right-branch branch))
        (else (error "bad bit -- CHOOSE-BRANCH" bit))))

; exercise 2.67
(define sample-tree
  (make-code-tree (make-leaf 'A 4)
                  (make-code-tree
                  (make-leaf 'B 2)
                  (make-code-tree (make-leaf 'D 1)
                                  (make-leaf 'C 1)))))
(define sample-message '(0 1 1 0 0 1 0 1 0 1 1 1 0))

(define (encode message tree)
  (if (null? message)
      '()
      (append (encode-symbol (car message) tree)
              (encode (cdr message) tree))))

; answer
(define (encode-symbol sy tree)
  (define (recv current-branch)
    (cond ((leaf? current-branch) null)
          ((element-of-set? sy (symbols (left-branch current-branch)))
           (cons 0 (recv (left-branch current-branch))))
          (else (cons 1 (recv (right-branch current-branch))))))
  (if (not (element-of-set? sy (symbols tree)))
      (error "bad message -- A CHARACTER NOT IN MESSAGE" sy)
      (recv tree)))

; execute
sample-tree
sample-message
(decode sample-message sample-tree)
(encode (decode sample-message sample-tree) sample-tree)

크리에이티브 커먼즈 라이선스

이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이선스에 따라 이용하실 수 있습니다.