이 문제는 이차 미분 방정식의 일반적인 꼴을 만드는 문제입니다.

한글판에는 이 수식에 오탈자가 있습니다.

그래서 이 수식이 무엇을 말하는가 고민을 했습니다.OTL...

잘 되네요.^^

여기서 보인 결과는 연습문제 3.78에서 쓰인 수식입니다.

두 값이 같다는 것을 확인할 수 있습니다.^^

참조

해럴드 애빌슨, 김재우 역, <컴퓨터 프로그램의 구조와 해석>, 인사이트, 2007, pp. 456

; stream
(define true (= 0 0))
(define false (= 1 0))

(define (cons-stream a b)
  (cons a (delay b)))
(define the-empty-stream '())
(define stream-null? null?)
(define (stream-car stream) (car stream))
(define (stream-cdr stream) (force (cdr stream)))

; section 3.5
(define (stream-ref s n)
  (if (= n 0)
      (stream-car s)
      (stream-ref (stream-cdr s) (- n 1))))

(define (stream-for-each proc s)
  (if (stream-null? s)
      'done
      (begin (proc (stream-car s))
             (stream-for-each proc (stream-cdr s)))))

(define (display-stream s)
  (stream-for-each display-line s))

(define (display-line x)
  (newline)
  (display x))

(define (stream-enumerate-interval low high)
  (if (> low high)
      the-empty-stream
      (cons-stream
       low
       (stream-enumerate-interval (+ low 1) high))))

(define (stream-filter pred stream)
  (cond ((stream-null? stream) the-empty-stream)
        ((pred (stream-car stream))
         (cons-stream (stream-car stream)
                      (stream-filter pred
                                     (stream-cdr stream))))
        (else (stream-filter pred (stream-cdr stream)))))

(define (memo-proc proc)
  (let ((already-run? false) (result false))
    (lambda ()
      (if (not already-run?)
          (begin (set! result (proc))
                 (set! already-run? true)
                 result)
          result))))

(define (scale-stream stream factor)
  (stream-map (lambda (x) (* x factor)) stream))

; exercise 3.50
(define (stream-map proc . argstreams)
  (if (stream-null? (car argstreams))
      the-empty-stream
      (cons-stream
       (apply proc (map stream-car argstreams))
       (apply stream-map
              (cons proc (map stream-cdr argstreams))))))

;;;SECTION 3.5.2
(define (add-streams s1 s2)
  (stream-map + s1 s2))

(define ones (cons-stream 1 ones))
(define integers (cons-stream 1 (add-streams ones integers)))

; exercise 3.54
(define (mul-streams s1 s2)
  (stream-map * s1 s2))

; exercise 3.55
(define (partial-sums S)
  (cons-stream (stream-car S) (add-streams (stream-cdr S)
                                           (partial-sums S))))

; exercise 3.56
(define (merge s1 s2)
  (cond ((stream-null? s1) s2)
        ((stream-null? s2) s1)
        (else
         (let ((s1car (stream-car s1))
               (s2car (stream-car s2)))
           (cond ((< s1car s2car)
                  (cons-stream s1car (merge (stream-cdr s1) s2)))
                 ((> s1car s2car)
                  (cons-stream s2car (merge s1 (stream-cdr s2))))
                 (else
                  (cons-stream s1car
                               (merge (stream-cdr s1)
                                      (stream-cdr s2)))))))))

; print-stream-n
(define (print-stream-n S n l)
  (define (iter i)
    (if (= i n)
        'done
        (begin (display (stream-ref S i))
               (display "   ")
               (if (= (remainder (+ i 1) l) 0)
                   (newline))
               (iter (+ i 1)))))
  (iter 0))

; exercise 3.59
(define (div-streams s1 s2)
  (stream-map / s1 s2))

; section 3.5.4
(define (solve f y0 dt)
  (define y (integral (delay dy) y0 dt))
  (define dy (stream-map f y))
  y)

;(define (integral delayed-integrand initial-value dt)
;  (define int
;    (cons-stream initial-value
;                 (let ((integrand (force delayed-integrand)))
;                   (add-streams (scale-stream integrand dt)
;                                int))))
;  int)

; exercise 3.77
(define (integral delayed-integrand initial-value dt)
  (define (int integrand initial-value)
    (cons-stream initial-value
                 (if (stream-null? integrand)
                     the-empty-stream
                     (int (stream-cdr integrand)
                          (+ (* dt (stream-car integrand))
                             initial-value)))))
  (int (force delayed-integrand) initial-value))

; exercise 3.78
(define (solve-2nd a b dt y0 dy0)
  (define y (integral (delay dy) y0 dt))
  (define dy (integral (delay ddy) dy0 dt))
  (define ddy (add-streams (scale-stream dy a) (scale-stream y b)))
  y)

; exercise 3.79
(define (solve-2nd-2 f dt y0 dy0)
  (define y (integral (delay dy) y0 dt))
  (define dy (integral (delay ddy) dy0 dt))
  (define ddy (stream-map f y dy))
  y)

; execute
; y'' + y' - 2y = 0, y(0) = 4, y'(0) = -5
; y = e^t + 3e^(-2t)
; KREYSZIG, ADVANCED ENGINEERING MATHEMATICS 9TH EDITION, 2006, pp. 54, EXAMPLE 2
(stream-ref (solve-2nd -1 2 0.001 4 -5) 1000)
(stream-ref (solve-2nd -1 2 0.001 4 -5) 2000)
(stream-ref (solve-2nd -1 2 0.001 4 -5) 3000)
(stream-ref (solve-2nd -1 2 0.001 4 -5) 4000)
(stream-ref (solve-2nd -1 2 0.001 4 -5) 5000)
(newline) (newline)
(stream-ref (solve-2nd-2 (lambda (y dydt)
                           (+ (* -1 dydt) (* 2 y))) 0.001 4 -5) 1000)
(stream-ref (solve-2nd-2 (lambda (y dydt)
                           (+ (* -1 dydt) (* 2 y))) 0.001 4 -5) 2000)
(stream-ref (solve-2nd-2 (lambda (y dydt)
                           (+ (* -1 dydt) (* 2 y))) 0.001 4 -5) 3000)
(stream-ref (solve-2nd-2 (lambda (y dydt)
                           (+ (* -1 dydt) (* 2 y))) 0.001 4 -5) 4000)
(stream-ref (solve-2nd-2 (lambda (y dydt)
                           (+ (* -1 dydt) (* 2 y))) 0.001 4 -5) 5000)

크리에이티브 커먼즈 라이선스

이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이선스에 따라 이용하실 수 있습니다.